Автор перевода: Майкл "Antares" КлишинПредыдущая | Следующая | Оглавление

Selection.getEndIndex()

Доступность

Flash Player 5.

Синтаксис

Selection.getEndIndex() : Number

Параметры

Нет.

Возвращает

Целое число .

Описание

Метод; возвращает индекс последнего символа в выделенном фрагменте. Если ни одно текстовое поле не имеет фокуса или выделение отсутствует, возвращается -1. Отсчет индекса ведется от 0 (например, первому символу соответствует 0, второму — 1, и т.д.).

Пример

Пример взят из файла Strings.fla в папке HelpExamples. 

/* Определяем функцию, конвертирующую выделенный текст в нижний или верхний регистр. */
function convertCase(target, menuItem) {
  var beginIndex:Number = Selection.getBeginIndex();
  var endIndex:Number = Selection.getEndIndex();
  var tempString:String;
  // Убеждаемся в том, что текст действительно выделен.
  if (beginIndex>-1 && endIndex>-1) {
    // Сохраняем значение текста до выделенного фрагмента.
    tempString = target.text.slice(0, beginIndex);
    switch (menuItem.caption) {
    case 'В верхний регистр...' :
      // Если пользователь выбирает пункт "В верхний регистр..." в контекстном меню, конвертируем выделенный текст в верхний регистр.
      tempString += target.text.substring(beginIndex, endIndex).toUpperCase();
      break;
    case 'В нижний регистр...' :
      tempString += target.text.substring(beginIndex, endIndex).toLowerCase();
      break;
    }
    // "Добавляем" текст после выделенного фрагмента.
    tempString += target.text.slice(endIndex);
    // Присваиваем текст во временной переменной текстовому полю.
    target.text = tempString;
  }
}

Смотри файл Strings.fla для полной версии скрипта. Обычно путь к папке HelpExamples обычно выглядит так:

См. также

Selection.getBeginIndex()
Смотреть комментарии LiveDocs   Предыдущая | Следующая | Оглавление